تبلیغات

آموزش آپلود فایل با استفاده از FTP در بچ اسکریپت

در بچ فایل می‌توان با نوشتن چند خط دستور کوتاه، فایلی را از طریق پروتکل FTP به هاست مورد نظر آپلود کرد. این کار توسط دستور ftp انجام می‌گیرد؛ اما روش استفاده از این دستور کار چندان ساده‌ای نیست. در ادامه با ذکر مثال‌هایی، به روش کار آن می‌پردازیم.

مثال 1: آپلود یک فایل در ریشه هاست

به مثال زیر دقت کنید:

@ECHO off

REM PART 1:
REM  Init FTP DATA
ECHO user USERNAME> fullkade-ftp-data.dat
ECHO PASSWORD>> fullkade-ftp-data.dat
ECHO put FILEPATH>> fullkade-ftp-data.dat
ECHO quit>> fullkade-ftp-data.dat

REM PART 2:
REM  Run FTP:
ftp -n -s:fullkade-ftp-data.dat fullkade.com

REM PART 3:
REM  Delete FTP Data:
DEL fullkade-ftp-data.dat

PAUSE

اسکریپت بالا از چند بخش تشکیل شده است.

  • بخش اول:
    داده‌های FTP می‌باشد؛ شامل نام کاربری، پسورد و مسیر فایل مورد نظر جهت آپلود است. این داده‌ها، بایستی در یک فایل متنی ذخیره شوند؛ که آن فایل توسط دستور ftp لود خواهد شد. این فایل یک فایل متنی ساده است و ما در کد بالا نام آن را fullkade-ftp-data.dat قرار دادیم. از دستور ECHO برای نوشتن در این فایل متنی استفاده شده است. به‌جای USERNAME بایستی نام کرابری و به‌جای PASSWORD بایستی رمز عبور قرار داده شود. همچنین به‌جای FILEPATH نیز مسیر کامل فایل جهت آپلود قرار می‌گیرد.
  • بخش دوم:
    توسط دستور ftp، فایل دیتای ایجاد شده برای آن بارگزاری شده و در ادامه مشخص می‌کنیم که به چه هاستی متصل شود؛ که در بالا fullkade.com است.
  • بخش سوم:
    در نهایت فایل دیتای اف تی پی را حذف می‌کنیم؛ چرا که دیگر به آن نیازی نداریم.

کد بالا کمبودهایی دارد. برای مثال نمی‌توان مشخص کرد که فایل در چه مسیری از هاست آپلود شود. این فایل به‌‍‌صورت پیشفرض در ریشه‌های هاست آپلود می‌شود.

مثال 2: آپلود با جزئیات بیشتر

به مثال زیر دقت کنید:

@ECHO off

REM Part 1:
REM Init FTP Data
(
    ECHO open fullkade.com
    ECHO USERNAME
    ECHO PASSWORD
    ECHO lcd "D:\FuLLKade-Notes"
    ECHO cd  public_html
    ECHO binary
    ECHO mput *.zip
    ECHO disconnect
    ECHO bye
) > fullkade-ftp-details.dat

REM Part 2:
REM  Run FTP
ftp -v -i -s:"fullkade-ftp-details.dat"

REM Part 3:
REM  Delete FTP Data
DEL fullkade-ftp-details.dat

PAUSE

اسکریپت بالا از چند بخش تشکیل شده است.

  • بخش اول:
    همانند مثال قبل است. با این تفاوت که در اینجا، اطلاعات نوشته شده در دیتای اف تی پی بیشتر است. در ابتدا توسط open، آن سرور اف تی پی که قصد اتصال به آن را داریم مشخص کرده‌ایم؛ که در مثال بالا fullkade.com است. سپس به‌ترتیب نام کاربری و پسورد را بایستی قرار دهیم. این دو به‌جای USERNAME و PASSWORD قرار می‌گیرند. سپس مسیر پوشه‌ای که قصد داریم فایل یا فایل‌هایی را از داخل آن به سرور آپلود کنیم را مشخص کرده‌ایم؛ که این کار توسط lcd انجام گرفته و در ادامه هم با cd مشخص می‌کنیم که فایل‌ها در چه مسیری از سرور اف تی پی آپلود شوند. سپس نوع فایل‌ها را binary مشخص کرده و با دستور mput گفته‌ایم که تمامی فایل‌های zip آپلود شوند. در نهایت نیز اف تی پی را دیسکانکت کرده‌ایم.
  • بخش دوم:
    همانند بخش دوم مثال قبل است؛ با این تفاوت که دیگر نیازی به وارد کردن سرور اف تی پی نیست.
  • بخش سوم:
    در نهایت فایل دیتای اف تی پی را حذف می‌کنیم؛ چرا که دیگر به آن نیازی نداریم.

اینجا مشکلات مثال قبلی نیز حل شده‌اند. علاوه‌بر آپلود یک فایل نیز می‌توانیم چندین فایل را نیز آپلود کنیم. برای مثال تمامی فایل‌های زیپ یا هرچیز دیگری که نیاز داشته باشیم. اگر هم قصد آپلود فایل خاصی را داشتیم، بایستی نام آن را به‌صورت کامل بنویسیم.

آموش آپلود چندین فایل به طور همزمان در بچ فایل، آموزش آپلود تمامی فایل های یک پوشه به سرور اف تی پی در بچ اسکریپت، کد آپلود فایل در بچ اسکریپت

درباره نویسنده

هادی اکبرزاده

[ مدیر فول کده ]

یه کلاسِ تعریف نشده ... فقط برای ارتباط کاری تلگرام پیام بدید ...

پاسخ دهید

نشانی ایمیل شما منتشر نخواهد شد. بخش‌های موردنیاز علامت‌گذاری شده‌اند *

نظرات ثبت شده بدون دیدگاه

توضیحات پیشنهادی نظرات اشتراک